| Categoría : Administración
Autor : Marti Riera
Título : RTVUSRDIR - Recupera ID Usuario
Descripción del truco:
Este mandato dado un perfil de usuario recupera su
USRID y DIRECCION del directorio.
Si no existe devuelve blancos.
/*----------------------------------------------------------------MRB*/
/* Recupera ID de usuario y direccion de un usuario */
/*-------------------------------------------------------------------*/
/* Marti Riera 24/01/2005 */
/* http://www.recursos-as400.com/ */
/* mailto:mrierab@teleline.es */
/*-------------------------------------------------------------------*/
PGM PARM(&USER &USRID &DIR)
DCL VAR(&USER) TYPE(*CHAR) LEN(10)
DCL VAR(&USRID) TYPE(*CHAR) LEN(8)
DCL VAR(&DIR) TYPE(*CHAR) LEN(8)
DCL VAR(&EOF) TYPE(*LGL) VALUE('0')
DCLF FILE(DSPDIRE)
/* Comprobar si existe el usuario */
IF COND(&USER = '*CURRENT') THEN(DO)
RTVJOBA USER(&USER)
ENDDO
ELSE DO
CHKOBJ OBJ(&USER) OBJTYPE(*USRPRF)
MONMSG MSGID(CPF9801) EXEC(DO)
SNDPGMMSG MSGID(CPF9801) MSGF(QCPFMSG) MSGDTA(&USER +
*CAT 'QSYS ' *CAT 'USRPRF')
GOTO END
ENDDO
ENDDO
/* Cargar variables de trabajo */
CHGVAR VAR(&USRID) VALUE(' ')
CHGVAR VAR(&DIR) VALUE(' ')
DSPDIRE USER(&USER) OUTPUT(*OUTFILE) OUTFILE(QTEMP/DSPDIRE)
MONMSG MSGID(CPF9006) EXEC(GOTO END)
/* Bucle de lectura */
READ: RCVF
MONMSG MSGID(CPF0864) EXEC(CHGVAR VAR(&EOF) VALUE('1'))
IF COND(&EOF *NE '1') THEN(DO)
CHGVAR VAR(&USRID) VALUE(&WOSDDEN)
CHGVAR VAR(&DIR) VALUE(&WOSDDGN)
GOTO READ
ENDDO
/* Fin de programa */
END:
RETURN
ENDPGM
/*----------------------------------------------------------------MRB*/
/* Recupera ID de usuario y direccion de un usuario */
/* Marti Riera 24/01/2005 */
/* http://www.recursos-as400.com/ */
/* mailto:mrierab@teleline.es */
/*-------------------------------------------------------------------*/
/* Compilar con PGM(RTVUSRDIRC) y ALLOW(*IPGM *BPGM) */
/*-------------------------------------------------------------------*/
CMD PROMPT('Recupera ID Usuario')
PARM KWD(USER) TYPE(*NAME) LEN(10) +
SPCVAL((*CURRENT)) MIN(1) PROMPT('Usuario')
PARM KWD(USRID) TYPE(*CHAR) LEN(8) RTNVAL(*YES) +
PROMPT('ID usuario')
PARM KWD(DIR) TYPE(*CHAR) LEN(8) RTNVAL(*YES) +
PROMPT('Direccion')
Ver
código fuente CL
Ver código fuente mandato
Fecha 12-07-2005 Tienes algún truco que quieras compartir con todos
los profesionales de Recursos iSeries i5 AS400?. Envianoslo
y si resulta seleccionado te enviaremos un vale de
Amazon por valor de 50$
|
