A*%%TS  SD  20040513  044746  QPGMR       REL-V5R2M0  5722-WDS
     A*%%EC
     A                                      DSPSIZ(24 80 *DS3)
     A                                      CF03(03)
     A          R PANT01
     A*%%TS  SD  20040513  044746  QPGMR       REL-V5R2M0  5722-WDS
     A                                      WINDOW(7 9 10 40)
     A                                      WDWBORDER((*DSPATR RI) (*CHAR '    -
     A                                          '))
     A                                      WDWTITLE((*TEXT 'Verifica Contraseñ-
     A                                      a de Usuario') (*COLOR WHT) (*DSPAT-
     A                                      R RI))
     A            WFUNC         40A  O  1  1DSPATR(HI)
     A                                  3  5'Usuario:'
     A                                      DSPATR(HI)
     A            WUSUAR        10A  B  3 18DSPATR(UL)
     A                                  4  5'Contraseña:'
     A                                      DSPATR(HI)
     A            WCONTR        10A  B  4 18DSPATR(ND)
     A                                      DSPATR(UL)
     A            MSG1          39A  O  6  1
     A            MSG2          39A  O  7  1
     A                                  9  7'Intro=Validar'
     A                                      DSPATR(HI)
     A                                  9 25'F3=Salir'
     A                                      DSPATR(HI)
     A          R FOOT1
     A                                      CLRL(*NO)
     A                                      OVERLAY
     A                                      FRCDTA
     A          R FOOT2
     A                                      KEEP
     A                                      ASSUME
     A                                  2  2' '
     *******************************************************************
     **                                                              **
     **  PROGRAMA    : VERIGRPG                                      **
     **  OBJETIVO    : VERIFICA CONTRASEÑA DE USUARIO                **
     **  PROGRAMADOR : JORGE NATALIO LAZARO 28/04/2004               **
     **                                                              **
     *******************************************************************
     FVERIFWS CF  E                    WORKSTN
     *******************************************************************
     I**  Data Structure-Error
     IERRCDE      DS                            272
     I I            256                   B   1   40BYTPRO
     I I                                  B   5   80BYTAVL
     I                                        9  15 EXCPID
     I                                       16  16 RSVD
     I                                       17 272 EXCPDT
     I**  Data Structure-Mensaje
     IMSGINF      DS                            280
     I                                    B   1   40BYTRET
     I                                    B   5   80BYTAV2
     I                                    B   9  120LOMRET
     I                                    B  13  160LOMAVL
     I                                    B  17  200LOMHRE
     I                                    B  21  240LOMHAV
     I                                       25 280 MSGTXT
     I**
     I            DS
     I I            280                   B   1   40LENGMI
     I I                                  B   5   80LENGMS
     I**
     I            DS
     I                                        1  20 MSGFQ
     I I            'QCPFMSG   '              1  10 MSGUNO
     I I            '*LIBL     '             11  20 MSGDOS
     I**
     I            DS
     I                                        1  39 MSG1
     I                                       40  78 MSG2
     I                                        1  78 TXTMSG
     C**  Parametro de Output- Usuario
     C           *ENTRY    PLIST
     C                     PARM           USUARI 10
     C**   Parámetros llamada API-QSYGETPH
     C           PARM1     PLIST
     C                     PARM           WUSUAR
     C                     PARM           WCONTR
     C                     PARM           PROFIL 12
     C                     PARM           ERRCDE
     C**   Parámetros llamada API-QMHRTVM
     C           PARM2     PLIST
     C                     PARM           MSGINF
     C                     PARM           LENGMI
     C                     PARM 'RTVM0100'FORMAT  8
     C                     PARM EXCPID    MSGIND  7
     C                     PARM MSGFQ     QMSGF  20
     C                     PARM           MSGDTA 52
     C                     PARM           LENGMS
     C                     PARM '*YES'    REPLSV 10
     C                     PARM '*YES'    RFCTCH 10
     C                     PARM           ERRCDE
     C** Inicio del programa
     C           *IN03     DOWEQ'0'
     C                     EXFMTPANT01
     C           *IN03     IFEQ '0'
     C                     CALL 'QSYGETPH'PARM1
     C                     MOVE *BLANKS   TXTMSG
     C           BYTAVL    IFNE 0                          Error detectado
     C                     EXSR RERROR
     C                     MOVE *BLANKS   USUARI
     C                     ELSE
     C                     MOVE '1'       *IN03
     C                     MOVELWUSUAR    USUARI
     C                     ENDIF
     C                     ENDIF
     C                     ENDDO
     C                     MOVE '1'       *INLR
     C**  RUTINA DE ERROR
     C           RERROR    BEGSR
     C                     CALL 'QMHRTVM' PARM2
     C                     MOVE LOMAVL    X       40
     C           X         SUBSTMSGTXT:1  TXTMSG
     C                     ENDSR