A*================================================================
     A* ARCHIVO....: SCHFLDD
     A* DESCRIPCION: Buscar campo en archivo fuente.
     A* AUTOR......: Diego M. ACEVEDO  -Buenos Aires- Argentina
     A* 
     A*================================================================
     A                                      DSPSIZ(24 80 *DS3)
     A                                      PRINT
     A                                      CA03(03)
     A                                      CA12(12)
     A                                      ROLLUP(25)
     A                                      ROLLDOWN(26)
     A*================================================================
     A          R SFL1                      SFL
     A*================================================================
     A  39                                  SFLNXTCHG
     A            H1NRCD         6S 0H
     A            S1OPZ          2Y 0B 11  3COLOR(YLW)
     A                                      EDTCDE(Z)
     A            S1MEMBR       10A  O 11  7
     A            S1TEXT        50A  O 11 19
     A*================================================================
     A          R CTL1                      SFLCTL(SFL1)
     A*================================================================
     A N37                                  OVERLAY
     A N38                                  PUTOVR
     A                                      OVRDTA
     A                                      OVRATR
     A  30                                  SFLDSP
     A  31                                  SFLDSPCTL
     A  32                                  SFLCLR
     A  34                                  SFLEND(*MORE)
     A                                      SFLSIZ(0010)
     A                                      SFLPAG(0009)
     A            W$$SR1         4S 0H      SFLRCDNBR
     A                                  1  3USER
     A                                  1 27'Buscar Campo en miembro fuente'
     A                                  1 70DATE
     A                                      EDTCDE(Y)
     A                                  3  4'Archivo....:'
     A            C1SRCF        10   O  3 17
     A                                  4  4'Biblioteca.:'
     A            C1SRCL        10   O  4 17
     A                                  5  4'Campo......:'
     A            C1FIELD       14A  O  5 17
     A                                  6  4'Posici¢n...:'
     A            C1POSIT       14A  O  6 17
     A                                  8  4'5=Visualizar fuente  '
     A                                      COLOR(PNK)
     A                                 10  3'Op   Miembro    Descripci¢n'
     A                                      DSPATR(HI)
     A*================================================================
     A          R SFLMSG                    SFL
     A*================================================================
     A                                      SFLMSGRCD(24)
     A            NONE                      SFLMSGKEY
     A            P$$PGM                    SFLPGMQ(10)
     A*================================================================
     A          R SFLCTL                    SFLCTL(SFLMSG)
     A*================================================================
     A                                      SFLSIZ(0002)
     A                                      SFLPAG(0001)
     A N37                                  OVERLAY
     A N38                                  PUTOVR
     A                                      OVRDTA
     A                                      OVRATR
     A                                      SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLINZ
     A  40                                  SFLEND
     A            P$$PGM                    SFLPGMQ(10)
     A                                 21  2'                                  -
     A                                                                         -
     A                                               '
     A                                      DSPATR(UL)
     A            W$$CK1        79   O 22  2
     A            W$$CK2        79   O 23  2