H            Y
     H*========================================================================*
     H* EJEMPLO ENVIO DE MENSAJES DE *BREAK A UN USUARIO UTILIZANDO            *
     H* PROGRAMA QEZSNDMG (EL MISMO QUE LLAMA EL ASSIST)
     H*========================================================================*
     I*DEFINICION DS DE SISTEMA (RECUPERA ATRIBUTOS JOB Y PROGRAMA)
     I¥¥DS       SDS
     I                                        1  10 ¥¥PGM
     I                                       81  90 ¥¥LIB
     I                                      244 253 ¥¥JOB
     I                                      254 263 ¥¥USER
     I                                      264 269 ¥¥JOBN
     I*DEFINICION PARAMETROS API QEZSNDMG
     I¥MHSND      DS
     I                                        1  10 ¥MTYPE
     I                                       11  20 ¥DLVRY
     I                                       21 275 ¥MSG
     I                                    B 276 2790¥MLEN
     I                                      280 289 ¥USER
     I                                    B 290 2930¥USRNB
     I                                    B 294 2970¥INDIC
     I                                    B 298 3010¥FUNCT
     I                                      302 302 ¥SHOW
     I                                      303 322 ¥QUEUE
     I                                      323 326 ¥NAMET
     I*ESTRUCTURA ERROR API
     IAPIERR      DS
     I                                    B   1   40QBYTPR
     I                                    B   5   80QBYTAV
     I                                        9  15 QEXCPI
     I                                       17  96 QEXCPD
     C*=========================================================================
     C*          MOVEMOS TEXTO DEL MENSAJE A VARIABLE ¥MSG  CHAR(255)
     C                     MOVEL'HOLA'    ¥MSG      P
     C                     CAT  ¥¥USER:1  ¥MSG
     C*          Numero de Bytes en la estructura de error API
     C                     Z-ADD96        QBYTPR
     C*
     C* ------------------------------
     C* GRUPO OPCIONAL DE PARAMETROS 1
     C* ------------------------------
     C* TIPO DE MENSAJE (*INFO,*INQ)           > SALIDA Ý CHAR(10)
     C* MODO DE ENTREGA (*BREAK,*NORMAL)       > SALIDA Ý CHAR(10)
     C* TEXTO DEL MENSAJE                      > SALIDA Ý CHAR(*)
     C* LONGITUD TEXTO DEL MENSAJE             > SALIDA Ý BINARY(4)
     C* LISTA DE USUARIOS DESTINATARIOS        > SALIDA Ý ARRAY CHAR(10)
     C* (admite valores *ALL,*ALLACT,*SYSOPR)
     C* NUMERO DE USUARIOS EN LA LISTA         > SALIDA Ý BINARY(4)
     C* INDICADOR MENSAJES ENVIADOS            < ENTRAD Ý BINARY(4)
     c*   0=Mensaje no enviado
     c*   1=Mensajes enviados
     C* TECLA DE FUNCION PULSADA (SI PROMPT)   < ENTRAD Ý BINARY(4)
     c*  -4=F3
     c*  -8=F12
     C* ESTRUCTURA ERROR API                   < ENTRAD Ý CHAR(*)
     C* ------------------------------
     C* GRUPO OPCIONAL DE PARAMETROS 2
     C* ------------------------------
     C* MOSTRAR PANTALLA ENVIO (Y/N)           > SALIDA Ý CHAR(1)
     C* COLA DE MENSAJE (COLA+BIBLIOTECA)      > SALIDA Ý CHAR(20)
     C* TIPO DE DESTINATARIOS EN LA LISTA      > SALIDA Ý CHAR(4)
     c*   *USR=Usuarios
     c*   *DSP=Dispositivos
     c*----------------------------------------------------------------
     C                     CALL 'QEZSNDMG'
     C                     PARM '*INFO'   ¥MTYPE
     C                     PARM '*BREAK'  ¥DLVRY
     C                     PARM           ¥MSG
     C                     PARM 255       ¥MLEN
     C                     PARM ¥¥USER    ¥USER
     C                     PARM 1         ¥USRNB
     C                     PARM           ¥INDIC
     C                     PARM           ¥FUNCT
     C                     PARM           APIERR
     C                     PARM 'N'       ¥SHOW
     C                     PARM           ¥QUEUE
     C                     PARM '*USR'    ¥NAMET
     C*
     C                     MOVEL*ON       *INLR