A                                      DSPSIZ(24 80 *DS3)
     A                                      INDARA
     A                                      CA03(03)
     A                                      CA12(12)
     A*================================================================
     A          R @ASFL                     SFL
     A*================================================================
     A  39                                  SFLNXTCHG
     A            W$FLEN         4S 0H
     A            W$OFST         4Y 0O 11  4EDTWRD('  0 ')
     A            W$DATA        50A  B 11 15
     A*================================================================
     A          R @ACTL                     SFLCTL(@ASFL)
     A*================================================================
     A                                      CF05(05)
     A                                      CF17(17)
     A                                      CF18(18)
     A                                      ROLLUP(25)
     A                                      ROLLDOWN(26)
     A                                      SETOF(36)
     A N37                                  OVERLAY
     A N38                                  PUTOVR
     A                                      OVRDTA
     A                                      OVRATR
     A  30                                  SFLDSP
     A  31                                  SFLDSPCTL
     A  32                                  SFLCLR
     A  34                                  SFLEND(*MORE)
     A                                      SFLSIZ(0010)
     A                                      SFLPAG(0009)
     A            W$$SR1         4S 0H      SFLRCDNBR
     A            W$$LIN         3S 0H
     A            W$$COL         3S 0H
     A                                  1 30'Editar área de datos'
     A                                      DSPATR(HI)
     A                                  2 61'Sistema:'
     A                                  2 72SYSNAME
     A                                  3  2'Área datos . . . . . . :'
     A            W$ANAM        10A  O  3 28
     A                                  4  4'Biblioteca . . . . . :'
     A            W$ALIB        10A  O  4 30
     A                                  5  2'Tipo . . . . . . . . . :'
     A            W$ATYP        10A  O  5 28
     A                                  6  2'Longitud . . . . . . . :'
     A            W$ALEN         4S 0O  6 28
     A                                  7  2'Texto  . . . . . . . . :'
     A            W$ATXT        50A  O  7 28
     A                                  9 14'Valor'
     A                                      DSPATR(HI)
     A                                 10  2'Desplaz *...+....1....+....2.-
     A                                      ...+....3....+....4....+....5'
     A                                      DSPATR(HI)
     A*================================================================
     A          R SFLMSG                    SFL
     A*================================================================
     A                                      SFLMSGRCD(24)
     A            NONE                      SFLMSGKEY
     A            P$$PGM                    SFLPGMQ(10)
     A*================================================================
     A          R SFLCTL                    SFLCTL(SFLMSG)
     A*================================================================
     A N37                                  OVERLAY
     A N38                                  PUTOVR
     A                                      OVRDTA
     A                                      OVRATR
     A                                      SFLDSP
     A                                      SFLDSPCTL
     A                                      SFLINZ
     A  40                                  SFLEND
     A                                      SFLSIZ(0002)
     A                                      SFLPAG(0001)
     A            P$$PGM                    SFLPGMQ(10)
     A                                 21  2'                                
   -
     A                                                                       
   -
     A                                               '
     A                                      DSPATR(UL)
     A            W$$CK1        78   O 22  2
     A            W$$CK2        78   O 23  2