A*-------------------------------------------------------------MRB
     A* DRTOBJLCK - Display Real Time Object Lock
     A*----------------------------------------------------------------
     A                                      DSPSIZ(24 80 *DS3)
     A                                      MSGLOC(24)
     A                                      PRINT
     A*----------------------------------------------------------------
     A          R DRTTOP
     A                                  1  2'DRTOBJLCK'
     A                                  1 19' Display Real Time Object Lock '
     A                                      DSPATR(RI)
     A                                  1 51SYSNAME
     A                                      DSPATR(RI)
     A                                  1 73DATE EDTCDE(Y)
     A                                  2 73TIME EDTWRD('  :  :  ')
     A                                  3  2'Library:'
     A                                       COLOR(BLU)
     A            LIBNAM        10      3 11
     A                                  4  2'Type options, press Enter'
     A                                       COLOR(BLU)
     A                                  5  4'5=Work with Object Locks'
     A                                       COLOR(BLU)
     A                                  5 32'6=Work Object'
     A                                       COLOR(BLU)
     A                                  5 49'8=Work File'
     A                                       COLOR(BLU)
     A                                  7  2'Opt'
     A                                       COLOR(WHT)
     A                                  7  6'Object'
     A                                       COLOR(WHT)
     A                                  7 17'Type'
     A                                       COLOR(WHT)
     A                                  7 27'Lock Status'
     A                                       COLOR(WHT)
     A                                  7 41'Opt'
     A                                       COLOR(WHT)
     A                                  7 45'Object'
     A                                       COLOR(WHT)
     A                                  7 56'Type'
     A                                       COLOR(WHT)
     A                                  7 66'Lock Status'
     A                                       COLOR(WHT)
     A*----------------------------------------------------------------
     A          R DRTSFL                    SFL
     A                                      SFLNXTCHG
     A            REG            3  0H      TEXT('OCULTO')
     A            OPC            1   I  8  3
     A            OBJECT        10      8  6
     A  30                                  DSPATR(HI)
     A  31                                  COLOR(BLU)
     A  32                                  COLOR(YLW)
     A  33                                  COLOR(PNK)
     A  34                                  COLOR(TRQ)
     A  35                                  COLOR(RED)
     A            TYPE           8   H
     A            ATR            9      8 17
     A  30                                  DSPATR(HI)
     A  31                                  COLOR(BLU)
     A  32                                  COLOR(YLW)
     A  33                                  COLOR(PNK)
     A  34                                  COLOR(TRQ)
     A  35                                  COLOR(RED)
     A            STATUS        10      8 27
     A  30                                  DSPATR(HI)
     A  31                                  COLOR(BLU)
     A  32                                  COLOR(YLW)
     A  33                                  COLOR(PNK)
     A  34                                  COLOR(TRQ)
     A  35                                  COLOR(RED)
     A* Subfile 2
     A            OPC2           1   I  8 42
     A            OBJEC2        10      8 45
     A  40                                  DSPATR(HI)
     A  41                                  COLOR(BLU)
     A  42                                  COLOR(YLW)
     A  43                                  COLOR(PNK)
     A  44                                  COLOR(TRQ)
     A  45                                  COLOR(RED)
     A            TYPE2          8   H
     A            ATR2           9      8 56
     A  40                                  DSPATR(HI)
     A  41                                  COLOR(BLU)
     A  42                                  COLOR(YLW)
     A  43                                  COLOR(PNK)
     A  44                                  COLOR(TRQ)
     A  45                                  COLOR(RED)
     A            STATU2        10      8 66
     A  40                                  DSPATR(HI)
     A  41                                  COLOR(BLU)
     A  42                                  COLOR(YLW)
     A  43                                  COLOR(PNK)
     A  44                                  COLOR(TRQ)
     A  45                                  COLOR(RED)
     A*----------------------------------------------------------------
     A          R DRTCTL                    SFLCTL(DRTSFL)
     A                                      SFLPAG(013)
     A                                      SFLSIZ(026)
     A                                      CA03(03 'Exit')
     A                                      CA05(05 'Refresh')
     A                                      CA11(11 'Lock Only')
     A                                      CA12(12 'Cancel')
     A                                      CA21(21 'Command Entry')
     A                                      OVERLAY
     A N20                                  SFLDSPCTL
     A N20                                  SFLDSP
     A  20                                  SFLCLR
     A  20                                  SFLINZ
     A  30                                  SFLEND
     A                                      SFLRNA
     A            ERR            3  0H      SFLRCDNBR TEXT('Cursor error')
     A*----------------------------------------------------------------
     A          R DRTBOT
     A                                      OVERLAY
     A                                 22  1'F3=Exit' COLOR(BLU)
     A                                 22 25'F5=Refresh' COLOR(BLU)
     A*                                23 42'F11=Lock Only' COLOR(BLU)
     A                                 23  1'F12=Cancel' COLOR(BLU)
     A                                 23 54'F21=Command Entry' COLOR(BLU)