/*----------------------------------------------------------------MRB*/
/* Retrieve Job Status (calling API QWCRJBST)                        */
/* Marti Riera 10/07/2002                                            */
/* http://www.recursos-as400.com/                                    */
/* mailto:mrierab@teleline.es                                        */
/*-------------------------------------------------------------------*/
/* Values that can be returned for job status (&JOBSTS):             */
/* *ACTIVE  The job has started.                                     */
/*          This does not guarantee that the job is currently running:+
/*          HLDJOB, RLSJOB, TFRGRPJOB, TFRSECJOB, DSCJOB or MSGW.    */
/* *JOBQ    The job is currently on a job queue.                     */
/* *OUTQ    The job has completed running and has spooled output.    */
/* *ERROR   The Job with the specified job identifier does not exist.*/
/*-------------------------------------------------------------------*/
/* More information:                                                 */
/* http://publib.boulder.ibm.com/pubs/html/as400/v5r1/ic2931/index.htm?-
          info/apis/qwcrjbst.htm                                     */
/*-------------------------------------------------------------------*/
             PGM        PARM(&JOBNBR &JOBUSR &JOBNAM &JOBSTS)
             DCL        VAR(&JOBNBR) TYPE(*CHAR) LEN(6)
             DCL        VAR(&JOBUSR) TYPE(*CHAR) LEN(10)
             DCL        VAR(&JOBNAM) TYPE(*CHAR) LEN(10)
             DCL        VAR(&JOBSTS) TYPE(*CHAR) LEN(10)
             DCL        VAR(&RCV) TYPE(*CHAR) LEN(60)
             DCL        VAR(&RCVL) TYPE(*CHAR) LEN(4)
             DCL        VAR(&JOBID) TYPE(*CHAR) LEN(26)
             DCL        VAR(&JOBFMT) TYPE(*CHAR) LEN(8)
             DCL        VAR(&ERR) TYPE(*CHAR) LEN(30)
/* Set receiver variable to Hex 3C (= Decimal 60) */
             CHGVAR     VAR(&RCVL) VALUE(X'0000003C')
/* Use qualified job name format */
             CHGVAR     VAR(&JOBFMT) VALUE(JOBS0300)
/* Set qualified name of job */
             CHGVAR     VAR(&JOBID) VALUE(&JOBNAM *CAT &JOBUSR *CAT &JOBNBR)
/* Retrieve job status */
             CALL       PGM(QWCRJBST) PARM(&RCV &RCVL &JOBID &JOBFMT &ERR)
/* Extract job status from receiver */
             CHGVAR     VAR(&JOBSTS) VALUE(%SST(&RCV 9 10))
/* Send Results */
             SNDPGMMSG  MSG(&JOBID *BCAT &JOBFMT *BCAT &JOBSTS)
/* End program */
             RETURN
             ENDPGM