H*****************************************************************
     H*                                                               *
     H*    CALCULA EL N§ DE LA SEMANA ACTUAL CONSIDERANDO COMO        *
     H*                                                               *
     H*    1¦ SEMANA LA QUE CONTENGA EL PRIMER JUEVES.                *
     H*                                                               *
     H*****************************************************************
     H*                                                               *
     H*  Juan Ram¢n Garcia (JUANRA)              9 de Julio de 1.999  *
     H*****************************************************************
     I*
     I            DS
     I                                        1   60PRISEM
     I                                        1   20DIASEM
     I                                        3   40MESSEM
     I                                        5   60A¥OSEM
     I            DS
     I                                        1   60DOMING
     I                                        1   20DIADOM
     I                                        3   40MESDOM
     I                                        5   60A¥ODOM
     I           UDS
     I                                        1   20SEMANA
     I*
     C*
     C**
     C** CALCULA LA FECHA FINAL DE ESTA SEMANA (EL DOMINGO)
     C**
     C** CALCULA QUE DIA DE LA SEMANA ES HOY
     C                     CALL 'BDPG10'
     C                     PARM 50197     PGAFIN  80       FECHA INIC.
     C                     PARM UDATE     PGAFFI  80       FECHA FINAL
     C                     PARM ' DMA'    PGAFMT  4        FORMATO
     C                     PARM 0         PGADIA 150       DIAS DIFEREN
     C                     DIV  7         PGADIA
     C                     MVR            PGADIA
     C**
     C** NOTA: ESTE CALCULO ESTA BASADO EN QUE EL DIA 5.1.97 FUE
     C**       DOMINGO, EL CONTENIDO DE "PGADIA" NOS DICE QUE DIA
     C**       DE LA SEMANA ES HOY (0=DOMINGO, 1=LUNES, .....
     C**       4=JUEVES, ...... 6=SABADO)
     C**
     C** CALCULA LA FECHA DEL SIGUIENTE DOMINGO
B01  C           PGADIA    IFEQ 0
     C                     Z-ADDUDATE     DOMING
X01  C                     ELSE
     C           7         SUB  PGADIA    PG7SUM
     C                     CALL 'BDPG07'
     C                     PARM UDATE     PG7FEC  80       FECHA
     C                     PARM ' DMA'    PG7FMT  4        FORMATO
     C                     PARM           PG7SUM  50       DIAS A SUMARR
     C           DIADOM    PARM           PG7DIA  20       DIA (SALIDA)
     C           MESDOM    PARM           PG7MES  20       MES (SALIDA)
     C           A¥ODOM    PARM           PG7A¥O  40       A¥O (SALIDA)
E01  C                     ENDIF
     C**
     C** CALCULA FECHA DE PARTIDA (ANTERIOR DOMINGO AL PRIMER JUEVES)
     C**
     C** CALCULA QUE DIA ERA EL 1 DE ENERO
     C                     Z-ADDA¥ODOM    A¥OSEM
     C                     MOVEL'0101'    PRISEM
     C                     CALL 'BDPG10'
     C                     PARM 50197     PGAFIN           FECHA INIC.
     C                     PARM PRISEM    PGAFFI           FECHA FINAL
     C                     PARM ' DMA'    PGAFMT           FORMATO
     C                     PARM 0         PGADIA           DIAS DIFEREN
     C                     DIV  7         PGADIA
     C                     MVR            PGADIA
     C**
     C** NOTA: ESTE CALCULO ESTA BASADO EN QUE EL DIA 5.1.97 FUE
     C**       DOMINGO, EL CONTENIDO DE "PGADIA" NOS DICE QUE DIA
     C**       DE LA SEMANA FUE "PRISEM" (0=DOMINGO, 1=LUNES, .....
     C**       4=JUEVES, ...... 6=SABADO)
     C**
     C** CALCULA LA FECHA DEL PRIMER JUEVES DEL A¥O
     C           4         SUB  PGADIA    DIASEM
B01  C           DIASEM    IFLT 0                          NO ES +
     C                     ADD  7         DIASEM            LA MISMA +
E01  C                     ENDIF                            SEMANA.
     C                     ADD  1         DIASEM
     C** CALCULA LA FECHA DEL ANTERIOR DOMINGO
     C                     CALL 'BDPG08'
     C                     PARM PRISEM    PG8FEC  80       FECHA
     C                     PARM ' DMA'    PG8FMT  4        FORMATO
     C                     PARM 4         PG8RES  50       DIAS A RESTAR
     C           DIASEM    PARM           PG8DIA  20       DIA (SALIDA)
     C           MESSEM    PARM           PG8MES  20       MES (SALIDA)
     C           A¥OSEM    PARM           PG8A¥O  40       A¥O (SALIDA)
     C**
     C** CALCULA EL N§ DE LA SEMANA
     C**
     C                     CALL 'BDPG10'
     C                     PARM PRISEM    PGAFIN           FECHA INIC.
     C                     PARM DOMING    PGAFFI           FECHA FINAL
     C                     PARM ' DMA'    PGAFMT           FORMATO
     C                     PARM 0         PGADIA           DIAS DIFEREN
B01  C           PGADIA    IFEQ 0
     C                     Z-ADD53        SEMANA
X01  C                     ELSE
     C           PGADIA    DIV  7         SEMANA
     C                     MVR            PGADIA
B02  C           PGADIA    IFNE 0
     C                     ADD  1         SEMANA
E02  C                     ENDIF
E01  C                     ENDIF
     C                     SETON                     LR