H*³                                                             ³ Ä
     H*³ ÀAPLICACION..Ä GEBADA (GEstor de BAse de DAtos)             ³ Ä
     H*³ Ä                                                           ³ Ä
     H*³ ÀDESCRIPCION.Ä Comprobaci¢n de fechas                       ³ Ä
     H*³ Ä                                                           ³ Ä
     H*³ ÀANALISTA....Ä Juan Ram¢n Garcia                            ³ Ä
     H*³ ÀPROGRAMADOR.Ä Juan Ram¢n Garcia       ÀFECHA:Ä 23/10/94    ³ Ä
     H*³ Ä                                                           ³ Ä
     H*³ Ÿ COPYRIGHT.ÄJuan Ram¢n Garcia - 1.994Ä                   ³ Ä
     H*³ Ä                                                           ³ Ä
     H*³                                                               Ä
     H*
     E*
     E                    DCM    12  12  2 0             DIAS DE CADA MES
     E*
     I*
     I** DESGLOSE DE LA FECHA A COMPROBAR
     I            DS
     I                                        1   80FECHA
     I                                        1   20DIA
     I                                        3   40MES
     I                                        5   80A¥O
     I                                        7   80A¥O1
     I                                        1   2 XXDIA
     I                                        3   4 XXMES
     I                                        5   8 XXA¥O
     I                                        7   8 XXA¥O1
     I*
     C*
     C** DEFINICION DE PARAMETROS
     C           *ENTRY    PLIST
     C                     PARM           P1FECH  80       FECHA
     C                     PARM           P1FORM  4        FORMATO
     C                     PARM           P1DIA   20       DIA (SALIDA)
     C                     PARM           P1MES   20       MES (SALIDA)
     C                     PARM           P1A¥O   40       A¥O (SALIDA)
     C                     PARM           P1ERR   1        ERROR
     C                     MOVE *BLANK    P1ERR
     C                     Z-ADD0         P1DIA
     C                     Z-ADD0         P1MES
     C                     Z-ADD0         P1A¥O
     C                     Z-ADD0         FECHA
     C                     MOVELP1FECH    XXFECH  8
     C**
     C** COMPRUEBA EL FORMATO DE LA FECHA
     C**
B01  C                     SELEC
X01  C           P1FORM    WHEQ 'DMAA'
     C                     Z-ADDP1FECH    FECHA
X01  C           P1FORM    WHEQ 'AAMD'
     C                     MOVELXXFECH    XXA¥O
     C           2         SUBSTXXFECH:5  XXMES
     C                     MOVE P1FECH    XXDIA
X01  C           P1FORM    WHEQ 'MDAA'
     C                     MOVELXXFECH    XXMES
     C           2         SUBSTXXFECH:3  XXDIA
     C                     MOVE XXFECH    XXA¥O
X01  C           P1FORM    WHEQ 'DMA '
     C                     MOVELXXFECH    FECHA
     C           2         SUBSTXXFECH:5  XXA¥O1
     C                     EXSR CAMA¥O
X01  C           P1FORM    WHEQ 'AMD '
     C                     MOVELXXFECH    XXA¥O1
     C           2         SUBSTXXFECH:3  XXMES
     C           2         SUBSTXXFECH:5  XXDIA
     C                     EXSR CAMA¥O
X01  C           P1FORM    WHEQ 'MDA '
     C                     MOVELXXFECH    XXMES
     C           2         SUBSTXXFECH:3  XXDIA
     C           2         SUBSTXXFECH:5  XXA¥O1
     C                     EXSR CAMA¥O
X01  C           P1FORM    WHEQ ' DMA'
     C           2         SUBSTXXFECH:3  XXDIA
     C           2         SUBSTXXFECH:5  XXMES
     C                     MOVE XXFECH    XXA¥O1
     C                     EXSR CAMA¥O
X01  C           P1FORM    WHEQ ' AMD'
     C           2         SUBSTXXFECH:3  XXA¥O1
     C           2         SUBSTXXFECH:5  XXMES
     C                     MOVE XXFECH    XXDIA
     C                     EXSR CAMA¥O
X01  C           P1FORM    WHEQ ' MDA'
     C           2         SUBSTXXFECH:3  XXMES
     C           2         SUBSTXXFECH:5  XXDIA
     C                     MOVE XXFECH    XXA¥O1
     C                     EXSR CAMA¥O
X01  C                     OTHER
     C                     MOVEL'F'       P1ERR
     C                     GOTO FINAL
E01  C                     ENDSL
     C**
     C** COMPRUEBA SI EL MES ES VALIDO
     C**
B01  C           MES       IFEQ 0
     C           MES       ORGT 12
     C                     MOVEL'M'       P1ERR
     C                     GOTO FINAL
E01  C                     ENDIF
     C**
     C** SI EL MES ES FEBRERO COMPRUEBA SI EL A¥O ES BISIESTO
     C**
B01  C           MES       IFEQ 2
B02  C           A¥O1      IFEQ 0                          PRINC.SIGLO
     C                     MOVELA¥O       A¥OBIS  20
X02  C                     ELSE                            A¥O NORMAL
     C                     MOVE A¥O       A¥OBIS
E02  C                     ENDIF
     C                     DIV  4         A¥OBIS
     C                     MVR            A¥OBIS
B02  C           A¥OBIS    IFEQ 0                          BISIESTO
     C                     Z-ADD29        DCM,2
X02  C                     ELSE                            NO BISIESTO
     C                     Z-ADD28        DCM,2
E02  C                     ENDIF
E01  C                     ENDIF
     C**
     C** COMPRUEBA SI EL DIA ES VALIDO
     C**
B01  C           DIA       IFEQ 0
     C           DIA       ORGT DCM,MES
     C                     MOVEL'D'       P1ERR
     C                     GOTO FINAL
E01  C                     ENDIF
     C**
     C** SALIDA DEL PROGRAMA (SIN DESCARGARLO)
     C**
     C           FINAL     TAG
B01  C           P1ERR     IFEQ *BLANK
     C                     Z-ADDDIA       P1DIA
     C                     Z-ADDMES       P1MES
     C                     Z-ADDA¥O       P1A¥O
E01  C                     ENDIF
     C                     RETRN
     C**
     C** RUTINA DE CAMBIO DE A¥O DE 2 A 4 DIGITOS
     C**
     C           CAMA¥O    BEGSR
B01  C           A¥O1      IFGT 50
     C                     MOVEL'19'      XXA¥O
X01  C                     ELSE
     C                     MOVEL'20'      XXA¥O
E01  C                     ENDIF
     C                     ENDSR
** SERIE CON LOS DIAS DE CADA MES
312831303130313130313031